project(libkscreen)
set(libkscreen_VERSION_MAJOR 1)
set(libkscreen_VERSION_MINOR 0)
set(libkscreen_VERSION_RELEASE 4)
set(libkscreen_VERSION "${libkscreen_VERSION_MAJOR}.${libkscreen_VERSION_MINOR}.${libkscreen_VERSION_RELEASE}")
set(LIBKSCREEN_VERSION "${libkscreen_VERSION}")

configure_file(
    ${CMAKE_CURRENT_SOURCE_DIR}/libkscreen-config.h.cmake
    ${CMAKE_CURRENT_BINARY_DIR}/libkscreen-config.h
    @ONLY
)

if(POLICY CMP0017)
  cmake_policy(SET CMP0017 NEW)
endif()

enable_testing()
add_definitions(${KDE4_DEFINITIONS})
include(CheckCXXCompilerFlag)

macro_optional_find_package(XCB)
set_package_properties(XCB PROPERTIES DESCRIPTION "The X protocol C-language Binding (XCB) is a replacement for Xlib"
    URL "http://xcb.freedesktop.org/"
    TYPE OPTIONAL
    PURPOSE "Needed to build XRandR 1.1 backend"
)

macro_optional_find_package(X11_XCB)
set_package_properties(X11_XCB PROPERTIES DESCRIPTION "XCB extension to work with X11"
    URL "http://xcb.freedesktop.org/"
    TYPE OPTIONAL
    PURPOSE "Needed to build XRandR 1.1 backend"
)

if(ENABLE_TESTING)
    find_package(QJSON 0.8 REQUIRED)
    link_directories(${QJSON_LIBRARY_DIRS})
endif()

check_cxx_compiler_flag(-fvisibility=hidden _HAVE_VISIBILITY)
if (_HAVE_VISIBILITY AND NOT WIN32)
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")

  check_cxx_compiler_flag(-fvisibility-inlines-hidden _HAVE_VISIBILITY_INLINES)
  if (_HAVE_VISIBILITY_INLINES)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
  endif (_HAVE_VISIBILITY_INLINES)
endif (_HAVE_VISIBILITY AND NOT WIN32)

#
### lib64/32 support kde like
#
set(LIB_SUFFIX "" CACHE STRING "Define suffix for lib directory (32/64)")

set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin)
set(LIB_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})

set(INSTALL_TARGETS_DEFAULT_ARGS  RUNTIME DESTINATION "${BIN_INSTALL_DIR}"
                                  LIBRARY DESTINATION "${LIB_INSTALL_DIR}"
                                  ARCHIVE DESTINATION "${LIB_INSTALL_DIR}" COMPONENT Devel )

include_directories(${PROJECT_SOURCE_DIR}/src ${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR} ${QT_INCLUDES} ${KDE4_INCLUDES})

add_subdirectory(src)
add_subdirectory(backends)
if(ENABLE_TESTING)
    add_subdirectory(tests)
endif()

configure_file(${libkscreen_SOURCE_DIR}/LibKScreenConfig.cmake.in
               ${libkscreen_BINARY_DIR}/LibKScreenConfig.cmake
               @ONLY
)
# this file is used by to check if the installed version can be used.
macro_write_basic_cmake_version_file(${libkscreen_BINARY_DIR}/LibKScreenConfigVersion.cmake
                                     ${libkscreen_VERSION_MAJOR} ${libkscreen_VERSION_MINOR} ${libkscreen_VERSION_RELEASE})

install(FILES ${libkscreen_BINARY_DIR}/LibKScreenConfig.cmake ${libkscreen_BINARY_DIR}/LibKScreenConfigVersion.cmake
        DESTINATION ${LIB_INSTALL_DIR}/cmake/LibKScreen)

# Install the file with the exported targets
install(EXPORT kscreenLibraryTargets
        DESTINATION ${LIB_INSTALL_DIR}/cmake/LibKScreen
        FILE LibKScreenTargetsWithPrefix.cmake)