mirror of
https://bitbucket.org/smil3y/katie.git
synced 2025-02-25 03:12:56 +00:00
352f5471b7
it is not in the official repos and miniz will be used when zlib is not present (or detected) on the system so there is no need to build against and depend on it. openssl is not a hard requirement either but it is nice to have so I'm gonna keep it as dependency even tough it is in AUR Signed-off-by: Ivailo Monev <xakepa10@gmail.com>
64 lines
1.9 KiB
Bash
64 lines
1.9 KiB
Bash
# $Id:
|
|
# Maintainer: Ivailo Monev <xakepa10@gmail.com>
|
|
|
|
pkgname=mingw-w64-katie-git
|
|
pkgver=4.9.0.aa9772c
|
|
pkgrel=1
|
|
pkgdesc='C++ toolkit derived from the Qt 4.8 framework (mingw-w64)'
|
|
arch=('i686' 'x86_64')
|
|
url='https://github.com/fluxer/katie'
|
|
license=('LGPL' 'FDL' 'custom')
|
|
depends=('mingw-w64-openssl' 'mingw-w64-crt')
|
|
makedepends=('cmake' 'git' 'python' 'unifdef' 'mingw-w64-gcc')
|
|
source=("git+https://github.com/fluxer/katie")
|
|
sha1sums=('SKIP')
|
|
conflicts=('mingw-w64-katie')
|
|
options=('!strip' 'staticlibs' '!buildflags') # 'debug')
|
|
|
|
_arch="${CARCH}-w64-mingw32"
|
|
|
|
pkgver() {
|
|
cd katie
|
|
printf "4.9.0.%s" "$(git rev-parse --short HEAD)"
|
|
}
|
|
|
|
prepare() {
|
|
mkdir -p build
|
|
|
|
echo "set(CMAKE_INSTALL_DIR /usr/${_arch}/share/cmake)" \
|
|
>> katie/mkspecs/win32/vendor.cmake
|
|
echo 'set(QT_LIBRARIES_PATH "${QT_PREFIX_PATH}/lib/katie")' \
|
|
>> katie/mkspecs/win32/vendor.cmake
|
|
echo 'set(QT_PLUGINS_PATH "${QT_LIBRARIES_PATH}/plugins")' \
|
|
>> katie/mkspecs/win32/vendor.cmake
|
|
echo 'set(QT_IMPORTS_PATH "${QT_LIBRARIES_PATH}/imports")' \
|
|
>> katie/mkspecs/win32/vendor.cmake
|
|
echo 'set(QT_BINARIES_PATH "${QT_LIBRARIES_PATH}/bin")' \
|
|
>> katie/mkspecs/win32/vendor.cmake
|
|
echo 'set(QT_DATA_PATH "${QT_PREFIX_PATH}/share")' \
|
|
>> katie/mkspecs/win32/vendor.cmake
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
cmake ../katie \
|
|
-Wno-dev \
|
|
-DCMAKE_TOOLCHAIN_FILE=cmake/archlinux-mingw.cmake \
|
|
-DCMAKE_BUILD_TYPE=Release \
|
|
-DCMAKE_INSTALL_PREFIX=/usr/${_arch}
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd build
|
|
make DESTDIR="${pkgdir}" install
|
|
|
|
${_arch}-strip --strip-unneeded "${pkgdir}/usr/${_arch}/lib/katie/"*.dll
|
|
|
|
install -vDm644 ../katie/LGPL_EXCEPTION.txt \
|
|
"${pkgdir}/usr/share/licenses/mingw-w64-katie-git/LGPL_EXCEPTION.txt"
|
|
|
|
# bootstrap files, they should not be installed and this should be fixed
|
|
# in Katie itself
|
|
rm -rf "${pkgdir}/usr/local" "${pkgdir}/usr/share"
|
|
}
|