# $Id:
# Maintainer: Ivailo Monev <xakepa10@gmail.com>

pkgname=mingw-w64-katie-git
pkgver=4.9.0.8cb3f33
pkgrel=1
pkgdesc='C++ toolkit derived from the Qt 4.8 framework (mingw-w64)'
arch=('i686' 'x86_64')
url='https://github.com/fluxer/katie'
license=('LGPL' 'FDL' 'custom')
depends=('mingw-w64-openssl' 'mingw-w64-crt' 'mingw-w64-libpng')
makedepends=('cmake' 'git' 'python' 'unifdef' 'mingw-w64-gcc')
source=("git+https://github.com/fluxer/katie")
sha1sums=('SKIP')
conflicts=('mingw-w64-katie')
options=('!strip' 'staticlibs' '!buildflags') # 'debug')

_arch="${CARCH}-w64-mingw32"

pkgver() {
    cd katie
    printf "4.9.0.%s" "$(git rev-parse --short HEAD)"
}

prepare() {
    mkdir -p build
}

build() {
    cd build
    cmake ../katie \
        -Wno-dev \
        -DCMAKE_TOOLCHAIN_FILE=cmake/archlinux-mingw.cmake \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr/${_arch}
    make external_katie
    make
}

package() {
    cd build
    make DESTDIR="${pkgdir}" install

    ${_arch}-strip --strip-all "${pkgdir}/usr/${_arch}/lib/"*.exe
    ${_arch}-strip --strip-unneeded "${pkgdir}/usr/${_arch}/lib/"*.dll
    ${_arch}-strip --strip-debug "${pkgdir}/usr/${_arch}/lib/"*.a

    install -vDm644 ../katie/LGPL_EXCEPTION.txt \
        "${pkgdir}/usr/share/licenses/mingw-w64-katie-git/LGPL_EXCEPTION.txt"
}