# $Id$
# Maintainer: Ivailo Monev <xakepa10@gmail.com>

pkgname=polkit-katana-agent
pkgver=4.18.0.9150798
pkgrel=1
pkgdesc="Daemon providing a polkit authentication UI for Katana"
arch=('i686' 'x86_64')
url='http://fluxer.github.io/katana/'
license=('GPL')
groups=('katana')
depends=('katanalibs>=4.18.0' 'polkit-qt4')
makedepends=('cmake' 'git')
source=("git+https://github.com/fluxer/kde-playground.git")
sha1sums=('SKIP')
conflicts=('polkit-kde-agent')

pkgver() {
    cd kde-playground
    printf "4.18.0.%s" "$(git rev-parse --short HEAD)"
}

prepare() {
    mkdir -p build-agent build-kcm
}

build() {
    cd build-agent
    cmake ../kde-playground/polkit-kde-agent \
        -DCMAKE_BUILD_TYPE=Release \
        -DENABLE_TESTING=OFF \
        -DCMAKE_SKIP_INSTALL_RPATH=ON \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DWITH_KATIE=OFF
    make
    cd ../build-kcm
    cmake ../kde-playground/polkit-kde-kcmodules-1 \
        -DCMAKE_BUILD_TYPE=Release \
        -DENABLE_TESTING=OFF \
        -DCMAKE_SKIP_INSTALL_RPATH=ON \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DWITH_KATIE=OFF
    make
}

package() {
    make -C build-agent DESTDIR="${pkgdir}" install
    make -C build-kcm DESTDIR="${pkgdir}" install
}