mirror of
https://github.com/ARM-software/arm-trusted-firmware.git
synced 2025-04-16 01:24:27 +00:00
ed108b5605
This patch provides the following features and makes modifications listed below: - Individual APIAKey key generation for each CPU. - New key generation on every BL31 warm boot and TSP CPU On event. - Per-CPU storage of APIAKey added in percpu_data[] of cpu_data structure. - `plat_init_apiakey()` function replaced with `plat_init_apkey()` which returns 128-bit value and uses Generic timer physical counter value to increase the randomness of the generated key. The new function can be used for generation of all ARMv8.3-PAuth keys - ARMv8.3-PAuth specific code placed in `lib\extensions\pauth`. - New `pauth_init_enable_el1()` and `pauth_init_enable_el3()` functions generate, program and enable APIAKey_EL1 for EL1 and EL3 respectively; pauth_disable_el1()` and `pauth_disable_el3()` functions disable PAuth for EL1 and EL3 respectively; `pauth_load_bl31_apiakey()` loads saved per-CPU APIAKey_EL1 from cpu-data structure. - Combined `save_gp_pauth_registers()` function replaces calls to `save_gp_registers()` and `pauth_context_save()`; `restore_gp_pauth_registers()` replaces `pauth_context_restore()` and `restore_gp_registers()` calls. - `restore_gp_registers_eret()` function removed with corresponding code placed in `el3_exit()`. - Fixed the issue when `pauth_t pauth_ctx` structure allocated space for 12 uint64_t PAuth registers instead of 10 by removal of macro CTX_PACGAKEY_END from `include/lib/el3_runtime/aarch64/context.h` and assigning its value to CTX_PAUTH_REGS_END. - Use of MODE_SP_ELX and MODE_SP_EL0 macro definitions in `msr spsel` instruction instead of hard-coded values. - Changes in documentation related to ARMv8.3-PAuth and ARMv8.5-BTI. Change-Id: Id18b81cc46f52a783a7e6a09b9f149b6ce803211 Signed-off-by: Alexei Fedorov <Alexei.Fedorov@arm.com>
98 lines
2.7 KiB
ArmAsm
98 lines
2.7 KiB
ArmAsm
/*
|
|
* Copyright (c) 2017-2019, ARM Limited and Contributors. All rights reserved.
|
|
*
|
|
* SPDX-License-Identifier: BSD-3-Clause
|
|
*/
|
|
|
|
#include <arch.h>
|
|
#include <asm_macros.S>
|
|
#include <common/bl_common.h>
|
|
#include <el3_common_macros.S>
|
|
|
|
.globl bl2_entrypoint
|
|
.globl bl2_el3_run_image
|
|
.globl bl2_run_next_image
|
|
|
|
func bl2_entrypoint
|
|
/* Save arguments x0-x3 from previous Boot loader */
|
|
mov x20, x0
|
|
mov x21, x1
|
|
mov x22, x2
|
|
mov x23, x3
|
|
|
|
el3_entrypoint_common \
|
|
_init_sctlr=1 \
|
|
_warm_boot_mailbox=!PROGRAMMABLE_RESET_ADDRESS \
|
|
_secondary_cold_boot=!COLD_BOOT_SINGLE_CPU \
|
|
_init_memory=1 \
|
|
_init_c_runtime=1 \
|
|
_exception_vectors=bl2_el3_exceptions
|
|
|
|
/* ---------------------------------------------
|
|
* Restore parameters of boot rom
|
|
* ---------------------------------------------
|
|
*/
|
|
mov x0, x20
|
|
mov x1, x21
|
|
mov x2, x22
|
|
mov x3, x23
|
|
|
|
/* ---------------------------------------------
|
|
* Perform BL2 setup
|
|
* ---------------------------------------------
|
|
*/
|
|
bl bl2_el3_setup
|
|
|
|
#if ENABLE_PAUTH
|
|
/* ---------------------------------------------
|
|
* Program APIAKey_EL1 and enable pointer authentication.
|
|
* ---------------------------------------------
|
|
*/
|
|
bl pauth_init_enable_el3
|
|
#endif /* ENABLE_PAUTH */
|
|
|
|
/* ---------------------------------------------
|
|
* Jump to main function.
|
|
* ---------------------------------------------
|
|
*/
|
|
bl bl2_main
|
|
|
|
/* ---------------------------------------------
|
|
* Should never reach this point.
|
|
* ---------------------------------------------
|
|
*/
|
|
no_ret plat_panic_handler
|
|
endfunc bl2_entrypoint
|
|
|
|
func bl2_run_next_image
|
|
mov x20,x0
|
|
/* ---------------------------------------------
|
|
* MMU needs to be disabled because both BL2 and BL31 execute
|
|
* in EL3, and therefore share the same address space.
|
|
* BL31 will initialize the address space according to its
|
|
* own requirement.
|
|
* ---------------------------------------------
|
|
*/
|
|
bl disable_mmu_icache_el3
|
|
tlbi alle3
|
|
bl bl2_el3_plat_prepare_exit
|
|
|
|
#if ENABLE_PAUTH
|
|
/* ---------------------------------------------
|
|
* Disable pointer authentication before jumping
|
|
* to next boot image.
|
|
* ---------------------------------------------
|
|
*/
|
|
bl pauth_disable_el3
|
|
#endif /* ENABLE_PAUTH */
|
|
|
|
ldp x0, x1, [x20, #ENTRY_POINT_INFO_PC_OFFSET]
|
|
msr elr_el3, x0
|
|
msr spsr_el3, x1
|
|
|
|
ldp x6, x7, [x20, #(ENTRY_POINT_INFO_ARGS_OFFSET + 0x30)]
|
|
ldp x4, x5, [x20, #(ENTRY_POINT_INFO_ARGS_OFFSET + 0x20)]
|
|
ldp x2, x3, [x20, #(ENTRY_POINT_INFO_ARGS_OFFSET + 0x10)]
|
|
ldp x0, x1, [x20, #(ENTRY_POINT_INFO_ARGS_OFFSET + 0x0)]
|
|
eret
|
|
endfunc bl2_run_next_image
|